Hallo Wolfgang
Als MySQL Alternative bietet sich MariaDB an. Hier stimmt das Lizenzmodell noch und ist zudem auf jeder Synology bereits vorinstalliert.
Wenn Du bei den Fenstern den bArrayServer verwendest, kannst Du da die Sortierung nach jedem Einlesen neu bestimmen. Es geht sogar dynamisch bei einem Orderwechsel im Fenster und das ohne dass die Daten neu gelesen werden müssten.
Ein Beispiel aus meiner Fensterklasse:
Code: Select all
// Suchbegriff ist erstellt, jetzt die Daten mit Defaultsortierung einlesen und an Fenster hängen
SELF:_oSchuetzen:OrderBy(#nachname, #vorname, #ort)
SELF:_oSchuetzen:Where( cSuchStr )
SELF:_oSchuetzen:Execute()
Falls jetzt die Sortierung geändert werden muss, kann dies mit dem bArrayServer ohne neues Einlesen erfolgen
Code: Select all
SELF:_oSchuetzen:CreateOrder({|Server|RTrim(Server:VEREIN)+" "+Server:NACHNAME})
SELF:_oSchuetzen:SetOrder(1)
Betreffend Anpassung hast Du leider recht. Wenn man von DBF auf SQL wechselt fällt je nach vorliegender Business-Logik mehr oder weniger Anpassungsarbeit an. War bei mir auch so. Da ich jedoch schon vor über 10 Jahren damit begonnen habe alle Auswertungen mit mengenorientierten Abfragen zu erstellten und dafür je Datei eine eigene DbServerklasse geschrieben habe, war in diesem Bereich die Anpassung überschaubar.
Beim Wechsel von VO auf xSharp habe ich auch gleichzeitig den Wechsel von DBF auf SQL vollzogen. Dabei habe ich zuerst die ganze Applikation übernommen um zu sehen wo es Inkompatibilitäten hat. War zum Glück nicht allzu schlimm.
Danach habe ich die Serverklassen auf SQL angepasst ohne grosse Optimierung. Erst nachdem die Auswertungen so liefen wie unter VO habe ich begonnen die SQL Zugriffe zu optimieren.
Beispiel VO:
Code: Select all
METHOD GetSkStandblaetter( cSkNr, cJahr, dDatVon, dDatBis ) CLASS DbResultatBP
Local aRet as Array
Local aSave as Array
aSave := {}
// Umgebung sichern
self:SaveUmgebung( @aSave )
// IndexOrder setzen
self:SetOrder("SkJahr")
// auf erstes mögliches Resultat positionieren, kein Softseek
self:Seek( cSkNr+cJahr, false, false )
// alle Resultate der gewünschten Sektion lesen
aRet := {}
Do While .not. self:EoF .and. self:FIELDGET(#sknr) == cSkNr .and. self:FIELDGET(#jahr) == cJahr
// ist das Resultat innerhalb des gewünschten Zeitraumes?
If (self:FIELDGET(#Stbldrk1) >= dDatVon .and. self:FIELDGET(#Stbldrk1) <= dDatBis ) .or. ;
(self:FIELDGET(#Stbldrk2) >= dDatVon .and. self:FIELDGET(#Stbldrk2) <= dDatBis ) .or. ;
(self:FIELDGET(#Stbldrk3) >= dDatVon .and. self:FIELDGET(#Stbldrk3) <= dDatBis )
// gefundenen oder leeren Datensatz lesen
AAdd( aRet, LeseDatensatz( self ) )
Endif
// nächster Record
self:Skip(1)
enddo
// Umgebung restaurieren
self:RestoreUmgebung( aSave )
Return aRet
Beispiel xSharp und SQL:
Code: Select all
METHOD GetSkStandblaetter( cSkNr AS STRING, cJahr AS STRING, cAnlassId AS STRING, dDatVon AS DATE, dDatBis AS DATE ) AS ARRAY
LOCAL aRet AS ARRAY
//
SELF:cSql := "Select * from " + SELF:cTable + " Where verein_id = '" + cSkNr + "'"
SELF:cSql += " and jahr = '" + cJahr + "' and anlassid = '" + cAnlassId + "'"
SELF:cSql += " and STBLDRK1 >= '" + DToS(dDatVon) + "'"
SELF:cSql += " and STBLDRK1 <= '" + DToS(dDatBis) + "'"
aRet := SELF:GetDaten2Array( SELF:cSQL )
RETURN aRet
Heinrich
Ps:
Bei meinem Beispiel "xSharp_SQL_Beispiel.zip" hat sich ein Fehler eingeschlichen.
Methode "_GetPrimaryFields()", Zeile 177
falsch => AAdd( SELF:_aPrimaryFld, myField["ColumnName"]:ToString() )
richtig => AAdd( SELF:_aPrimaryFld, { myField["ColumnName"]:ToString() }) // Array anhängen
